/**
 * Lösungen zu den Übungen
 *
 * @author:  Timo Gnambs <timo@gnambs.at>
 * @version: 2004-11-17
 */



/* Übung II: Frequencies */

/* Häufigkeitstabelle für die Motive */
FREQUENCIES
  VARIABLES=motiv1 motiv2 motiv3 motiv4
  /ORDER=  ANALYSIS .

/* Ungültige Werte von LOT01 bis LOT10 (vgl. LOT10: der Wert 0) */
FREQUENCIES
  VARIABLES=lot01 lot02 lot03 lot04 lot05 lot06 lot07 lot08 lot09 lot10  
  /ORDER=  ANALYSIS .

/* Mögliche Eingabefehler bei INCOME und  WORKTIME */
CROSSTABS
  /TABLES=income  BY worktime
  /FORMAT= AVALUE TABLES
  /CELLS= COUNT
  /COUNT ROUND CELL .

/* Sind HEIGHT und WEIGHT normalverteilt (HEIGHT ist NV, WEIGHT ist nicht NV) */
FREQUENCIES
  VARIABLES=height weight  /FORMAT=NOTABLE
  /STATISTICS=SKEWNESS SESKEW KURTOSIS SEKURT
  /HISTOGRAM  NORMAL
  /ORDER=  ANALYSIS .





/* Übung III: Rekodieren */

/* Umpolen der Items */
RECODE lot03, lot04, lot08 (1 = 5) (2 = 4) (3 = 3) (4 = 2) (5 = 1).
EXE.

/*  Vier Altersgruppen */
RANK VARIABLES = age /NTILES (4) INTO agegr.
VARIABLE LABELS agegr 'Altersgruppen'.
EXE.





/* Übung IV: Syntax */

/* Mittelwert von LOT01 bis LOT10 */
COMPUTE mlot = MEAN(lot01 TO lot10).
VARIABLE LABELS mlot 'Mittelwert von LOT01 bis LOT10'.
EXE.


/* Gruppierungsvariable Akademiker */
DO IF (profession = 'Anwalt' OR profession = 'Arzt' OR profession = 'Lehrer' OR profession = 'Psychologe').
COMPUTE aka = 1.
ELSE IF(profession = 'Tischler' OR profession = 'Elektriker' OR profession = 'Student').
COMPUTE aka = 0.
END IF.
VARIABLE LABELS aka 'Akademiker'.
VALUE LABELS aka 0 'Nein' 1 'Ja'.
EXE.


/* Anzahl der Motive uid 16, 21 und 29 */
COUNT motivcnt = motiv1 TO motiv4 (1).

DO IF ($casenum = 1).
PRINT EJECT /'Anzahl der Motive der Datensätze mit UID 16, 21 oder 29'.
PRINT SPACE.
PRINT EJECT /'ID Anzahl'.
PRINT SPACE.
END IF.

DO IF (uid = 16 OR uid = 21 OR uid = 29).
PRINT /uid 1-2 motivcnt 5-6.
END IF.
EXE.


/* Wurzel von LOT01 bis LOT10 */
DO REPEAT a = lot01 TO lot10 /b = sqt01 TO sqt10.
COMPUTE b = SQRT(a).
END REPEAT.
EXE.